dolphin/Source/Core/AudioCommon/CMakeLists.txt

set(SRCS
  AudioCommon.cpp
  DPL2Decoder.cpp
  Mixer.cpp
  WaveFile.cpp
  NullSoundStream.cpp
)

add_dolphin_library(audiocommon "${SRCS}" "")

find_package(OpenSLES)
if(OPENSLES_FOUND)
  message(STATUS "OpenSLES found, enabling OpenSLES sound backend")
  target_sources(audiocommon PRIVATE OpenSLESStream.cpp)
  target_link_libraries(audiocommon PRIVATE OpenSLES::OpenSLES)
endif()

if(ENABLE_ALSA)
  find_package(ALSA)
  if(ALSA_FOUND)
    message(STATUS "ALSA found, enabling ALSA sound backend")
    target_sources(audiocommon PRIVATE AlsaSoundStream.cpp)
    target_link_libraries(audiocommon PRIVATE ALSA::ALSA)
    target_compile_definitions(audiocommon PRIVATE HAVE_ALSA=1)
  else()
    message(STATUS "ALSA NOT found, disabling ALSA sound backend")
  endif()
else()
  message(STATUS "ALSA explicitly disabled, disabling ALSA sound backend")
endif()

if(ENABLE_AO)
  find_package(AO)
  if(AO_FOUND)
    message(STATUS "ao found, enabling ao sound backend")
    target_sources(audiocommon PRIVATE AOSoundStream.cpp)
    target_link_libraries(audiocommon PRIVATE AO::AO)
    target_compile_definitions(audiocommon PRIVATE HAVE_AO=1)
  else()
    message(STATUS "ao NOT found, disabling ao sound backend")
  endif()
else()
  message(STATUS "ao explicitly disabled, disabling ao sound backend")
endif()

if(OPENAL_FOUND)
  target_sources(audiocommon PRIVATE OpenALStream.cpp aldlist.cpp)
  target_link_libraries(audiocommon PRIVATE ${OPENAL_LIBRARY} SoundTouch)
endif()

if(PULSEAUDIO_FOUND)
  target_sources(audiocommon PRIVATE PulseAudioStream.cpp)
  target_link_libraries(audiocommon PRIVATE ${PULSEAUDIO_LIBRARIES})
endif()

if(WIN32)
  target_sources(audiocommon PRIVATE XAudio2Stream.cpp)

  add_dolphin_library(audiocommon_xaudio27 "XAudio2_7Stream.cpp" "${LIBS}")
  target_include_directories(audiocommon_xaudio27 PRIVATE
    ${PROJECT_SOURCE_DIR}/Externals
    ${PROJECT_SOURCE_DIR}/Externals/XAudio2_7
  )
  target_link_libraries(audiocommon PRIVATE audiocommon_xaudio27)

elseif(APPLE)
  target_sources(audiocommon PRIVATE CoreAudioSoundStream.cpp)
endif()